Menyimpan Tabel di Excel Menjadi Format Gambar Dengan VBA

Pada artikel ini saya akan memberikan tutorial bagaimana cara menyimpan tabel di excel hanya dengan satu tombol menggunakan script macro VBA. Sebelum memulai tutorial pastikan sudah mengaktifkan fitur Developer, apabila belum diaktifkan anda bisa mengunjungi tutorial pada link ini.

Hal pertama yang harus dilakukan adalah membuat tombol. Untuk membuat tombol perhatikan langkah-langkah berikut:

1. Buka tab Developer dan pilih Insert.
2. Pada Form Controls pilih simbol persegi panjang seperti yang terlihat pada gambar di bawah.

3. Letakkan tombol pada lembar kerja excel dan secara otomatis akan membuka dialog macro.
4. Buat macro baru dengan nama *Konversi dan pilih New.

note

(*) Nama macro bisa diberikan sesuai keinginan

5. Setelah membuat macro, otomatis akan membuka lembar kerja VBA dengan nama macro yang telah dibuat sebelumnya.

6. Selanjutnya tambahkan script berikut ke dalam method macro tersebut.

Sub Konversi()
    Dim ChO As ChartObject, ExportName As String
    Dim CopyRange As Range
    Dim Pic As Picture
    Dim i As Long

    With ActiveSheet
      Set CopyRange = Range("C6:G16") 'sesuaikan range tabel yang ingin dikonversi
      If Not CopyRange Is Nothing Then
        Application.ScreenUpdating = False
        ExportName = Application.GetSaveAsFilename(InitialFileName:="Tabel_", fileFilter:="PNG Files (*.png), *.png")
        If Not ExportName = "False" Then
          CopyRange.Copy
          .Pictures.Paste
          Set Pic = .Pictures(.Pictures.Count)
          Set ChO = .ChartObjects.Add(Left:=10, Top:=10, Width:=Pic.Width, Height:=Pic.Height)
          Application.CutCopyMode = False
          Do
            DoEvents
            Pic.Copy
            DoEvents
            ChO.Chart.Paste
            DoEvents
            i = i + 1
          Loop Until (ChO.Chart.Shapes.Count > 0 Or i > 50)
            ChO.Chart.Export Filename:=ExportName, Filtername:="PNG"
            ChO.Delete
            Pic.Delete
        End If
        Application.ScreenUpdating = True
      End If
    End With
End Sub

info

Pada bagian Set CopyRange = Range("C6:G16") ubah "C6:G16" menjadi range tabel yang anda miliki.

7. Jalankan macro tersebut dengan menekan tombol yang telah dibuat sebelumnya.
8. Apabila semua sudah sesuai, otomatis akan membuka file explorer untuk menetukan lokasi gambar yang akan disimpan.

9. Simpan file tersebut.

~ SELESAI ~